今天把Android Studio升级到2.3之后，突然发现无法打开Android SDK下面的SDK Manager和AVD Manager两个文件，因为是更新Android Studio之后才打不开的，所以网上提到的一些设定java路径的方法是无效的，问题出在了更新上面。
SDK Manager本质上是执行tools目录下面的android命令，执行 tools/android 命令发现提示 The "android" command is deprecated.，Google了一下，果然发现Google将原来的SDK Mananger弃用了，官方建议的开启方式是，在Android Studio中打开，见下图：
新界面如下：
不过还是习惯原来的SDK Mananger，Google官方也在投票要求进行恢复，在CSDN上看到一篇文章对比了更新前后的tools目录下的变化，作者最后说在官网下载最新的sdk-tools然后覆盖，但是我写这篇文章的时候这样操作是无效的。后来研究了一下，其实只要修改一下tools/android.bat文件的内容即可，首先将现在的tools/android.bat备份一下，然后替换成如下的内容：
@echo off
rem Copyright (C) 2007 The Android Open Source Project
rem
rem Licensed under the Apache License, Version 2.0 (the "License");
rem you may not use this file except in compliance with the License.
rem You may obtain a copy of the License at
rem
rem http://www.apache.org/licenses/LICENSE-2.0
rem
rem Unless required by applicable law or agreed to in writing, software
rem distributed under the License is distributed on an "AS IS" BASIS,
rem WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
rem See the License for the specific language governing permissions and
rem limitations under the License.
rem Useful links:
rem Command-line reference:
rem http://technet.microsoft.com/en-us/library/bb490890.aspx
rem don't modify the caller's environment
setlocal enableextensions
rem Set up prog to be the path of this script, including following symlinks,
rem and set up progdir to be the fully-qualified pathname of its directory.
set prog=%~f0
rem Grab current directory before we change it
set work_dir=%cd%
rem Change current directory and drive to where the script is, to avoid
rem issues with directories containing whitespaces.
cd /d %~dp0
rem Check we have a valid Java.exe in the path.
set java_exe=
call lib\find_java.bat
if not defined java_exe goto :EOF
set jar_path=lib\sdkmanager.jar;lib\swtmenubar.jar
rem Set SWT.Jar path based on current architecture (x86 or x86_64)
for /f "delims=" %%a in ('"%java_exe%" -jar lib\archquery-26.0.0-dev.jar') do set swt_path=lib\%%a
:MkTempCopy
rem Copy android.bat and its required libs to a temp dir.
rem This avoids locking the tool dir in case the user is trying to update it.
set tmp_dir=%TEMP%\temp-android-tool
xcopy "%swt_path%" "%tmp_dir%\%swt_path%" /I /E /C /G /R /Y /Q > nul
copy /B /D /Y lib\common.jar "%tmp_dir%\lib\" > nul
copy /B /D /Y lib\commons-codec* "%tmp_dir%\lib\" > nul
copy /B /D /Y lib\commons-compress* "%tmp_dir%\lib\" > nul
copy /B /D /Y lib\commons-logging* "%tmp_dir%\lib\" > nul
copy /B /D /Y lib\dvlib.jar "%tmp_dir%\lib\" > nul
copy /B /D /Y lib\gson* "%tmp_dir%\lib\" > nul
copy /B /D /Y lib\guava* "%tmp_dir%\lib\" > nul
copy /B /D /Y lib\httpclient* "%tmp_dir%\lib\" > nul
copy /B /D /Y lib\httpcore* "%tmp_dir%\lib\" > nul
copy /B /D /Y lib\httpmime* "%tmp_dir%\lib\" > nul
copy /B /D /Y lib\layoutlib-api.jar "%tmp_dir%\lib\" > nul
copy /B /D /Y lib\org-eclipse-* "%tmp_dir%\lib\" > nul
copy /B /D /Y lib\sdk* "%tmp_dir%\lib\" > nul
copy /B /D /Y lib\swtmenubar.jar "%tmp_dir%\lib\" > nul
rem jar_path and swt_path are relative to PWD so we don't need to adjust them, just change dirs.
set tools_dir=%cd%
cd /d "%tmp_dir%"
:EndTempCopy
rem The global ANDROID_SWT always override the SWT.Jar path
if defined ANDROID_SWT set swt_path=%ANDROID_SWT%
if exist "%swt_path%" goto SetPath
echo ERROR: SWT folder '%swt_path%' does not exist.
echo Please set ANDROID_SWT to point to the folder containing swt.jar for your platform.
goto :EOF
:SetPath
rem Finally exec the java program and end here.
REM set REMOTE_DEBUG=-Xdebug -Xrunjdwp:transport=dt_socket,server=y,suspend=y,address=8000
call "%java_exe% %REMOTE_DEBUG%" "-Dcom.android.sdkmanager.toolsdir=%tools_dir%" "-Dcom.android.sdkmanager.workdir=%work_dir%" -classpath "%jar_path%;%swt_path%\swt.jar" com.android.sdkmanager.Main %*
rem EOF
其实就是原来的android.bat文件的内容，就是将43行里面的 lib\archquery.jar 修改为 lib\archquery-26.0.0-dev.jar 即可。熟悉的界面有回来了：
Mac下可以参考这篇文章：关于mac 里面的 android studio 2.3 里面的 android sdk manager 找不到问题。
参考资料：
android studio 更新2.3后，怎么打开sdk manager下载samples？
Standalone SDK Manager option in Android Studio 2.3
android SDK SDK Manager.exe 无法打开，一闪而过最终解决办法
关于mac 里面的 android studio 2.3 里面的 android sdk manager 找不到问题